home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Wonky Flux Batch 2019 02
/
Wonky_Flux_Batch_2019-02.zip
/
Wonky Flux Batch 2019-02
/
022 - HO Utilities - Clock Utility System.dsk
/
PRETTY.TIME.bas
< prev
next >
Wrap
BASIC Source File
|
2019-02-16
|
1KB
|
24 lines
100 REM PRETTY.TIME - Applied Engineering - 8/13/85 by dcj - modified 8/28/87 by jlh
110 IF PEEK(49048) < >187 THEN PRINT "//c clock not found": STOP
120 PRINT CHR$(4)"-BASIC.TIME"
130 CALL 970,TIME$
140 REM print day_of_week (text)
150 X$ = MID$ ("Sunday Monday Tuesday WednesdayThursday Friday Saturday ",9 * VAL( MID$ (TIME$,7,2)) +1,9)
160 IF RIGHT$(X$,1) = " " THEN X$ = LEFT$(X$, LEN(X$) -1): GOTO 160
170 PRINT X$", ";
180 REM print month (text)
190 X$ = MID$ ("January February March April May June July August SeptemberOctober November December ",9 * VAL( LEFT$(TIME$,2)) -8,9)
200 IF RIGHT$(X$,1) = " " THEN X$ = LEFT$(X$, LEN(X$) -1): GOTO 200
210 PRINT X$" ";
220 REM print day_of_month (digits)
230 PRINT VAL( MID$ (TIME$,4,2))", ";
240 PRINT "19" INT( PEEK(49041)/2)". ";: REM print year
250 REM print hours in 12 hour format (digits)
260 H% = VAL( MID$ (TIME$,9,2))
270 M$ = "A": IF H% >11 THEN H% = H% -12:M$ = "P"
280 IF NOT H% THEN H% = 12
290 PRINT H%;
300 REM print minutes and seconds (digits)
310 PRINT MID$ (TIME$,11,6);" ";
320 REM print AM or PM per hours
330 PRINT M$"M"